110    ! CONCURRENT PROCESS
120    !
130    !
140    ASSIGN @E5100 TO 717
150    CLEAR @E5100
160    DIM Pnext(1:10),Fnext(1:10)
170    Ll=5
180    !
190    GOSUB Setting
200   GOSUB Thrucal
210   GOSUB Measure
220   STOP
230   !
240 Setting:       !
250   Fc=7.E+7     !70MHZ
260   Fspan=100000 !100kHz
270   Ifbw=8000    !8kHz
280   Nop=201
290   !
300   OUTPUT @E5100;"PRES"
310   OUTPUT @E5100;"POIN ";Nop
320   OUTPUT @E5100;"CHAN1;ANAMODE GAINP;MEAS AR;FMT LOGM"
330   OUTPUT @E5100;"HOLD"
340   OUTPUT @E5100;"CENT ";Fc;";SPAN ";Fspan
350   OUTPUT @E5100;"IFBW ";Ifbw
360   RETURN
370   !
380 Thrucal:  !
390   OUTPUT @E5100;"CALI RESP"  !Select and execute THRU CAL
391   INPUT "CONNECT THRU, THEN PRESS [RETURN].",Dum$
400   OUTPUT @E5100;"STANC?"
410   ENTER @E5100;Tmp
420   OUTPUT @E5100;"RESPDONE?"
430   ENTER @E5100;Tmp
431   INPUT "CONNECT DUT, THEN PRESS [RETURN].",Dum$
440   RETURN
450   !
460 Measure:  !
470   OUTPUT @E5100;"ANAOCH1"   ! Select channel for analysis and set analysis range
480   OUTPUT @E5100;"ANARFULL"  !
490   OUTPUT @E5100;"ANAODATA"  !
500   !
510   N=100
520   INPUT "Enter loop N :",N
530   Tstart=TIMEDATE
540   OUTPUT @E5100;"TRIGMEAS"  !1st. measurement
550   I=1
560   WHILE I<=N            !Repeat measurement and analysis
570   OUTPUT @E5100;"MOVADARY"  !Enters measurement data for parallel processing
580   OUTPUT @E5100;"TRIGMEAS"  ! Triggers measurement for parallel processing
590   OUTPUT @E5100;"ADTOTRAC"  !Starts parallel processing
600   OUTPUT @E5100;"PEAK?"     !*Commands executed in parallel processing
610   ENTER @E5100;Pmax,Fmax    !*
620   !
630   FOR K=1 TO Ll             !
640   OUTPUT @E5100;"NEXPK?"    !*
650   ENTER @E5100;Pnext(K),Fnext(K) !*
660   !
670   NEXT K
680   I=I+1
690   END WHILE 
700   Tstop=TIMEDATE
710   !
720   PRINT "PEAK(MAX) :";Pmax;"[dB] @";Fmax/1.E+6;"[MHz]"
730   FOR K=1 TO Ll
740   PRINT "PEAK(NEXT[";K;"]):";Pnext(K);"[dB] @";Fnext(K)/1.E+6;"[MHz]"
750   NEXT K
760   PRINT "LOOP :";N;" NEXT[K] :";Ll
770   PRINT "TIME(AVE.) : ";(Tstop-Tstart)/N*1000;"[msec]"
780   RETURN
790   !
800   END
5000   !*************************************************
5010   !* DESCRIPTION:  Agilent E5100A/B Sample Program
5020   !*
5030   !* AUTHOR:       Agilent Technologies Japan, Ltd.
5040   !* CREATED:      05/01/2008
5050   !* PROGRAM NAME: PARA_E
5060   !* REVISION:     A.02.01
5070   !*
5080   !*     Copyright (c) Agilent Technologies,
5090   !*              All rights reserved.
5100   !*
5110   !*
5120   !*  Customer shall have the personal, non-
5130   !* transferable rights to use, copy or modify
5140   !* this SAMPLE PROGRAM for Customer's internal
5150   !* operations. Customer shall use the SAMPLE
5160   !* PROGRAM solely and exclusively for its own
5170   !* purpose and shall not license, lease, market
5180   !* or distribute the SAMPLE PROGRAM or
5190   !* modification or any part thereof.
5200   !*
5210   !*  Agilent Technologies shall not be liable for
5220   !* the quality, performance or behavior of the
5230   !* SAMPLE PROGRAM. Agilent Technologies especially
5240   !* disclaims that the operation of the SAMPLE
5250   !* PROGRAM shall be uninterrupted or error free.
5260   !* This SAMPLE PROGRAM is provided AS IS.
5270   !*
5280   !*  AGILENT TECHNOLOGIES DISCLAIMS THE IMPLIED
5290   !* WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
5300   !* A PARTICULAR PURPOSE.
5310   !*
5320   !*  Agilent Technologies shall not be liable for
5330   !* any infringement of any patent, trademark,
5340   !* copyright or other proprietary rights by the
5350   !* SAMPLE PROGRAM or its use. Agilent Technologies
5360   !* does not warrant that the SAMPLE PROGRAM is
5370   !* free from infringements or such rights of third
5380   !* parties. However, Agilent Technologies will not
5390   !* knowingly infringe or deliver a software that
5400   !* infringes the patent, trademark, copyright or
5410   !* other proprietary right of a third party.
5420   !*
5430   !*************************************************