1000 ! RE-SAVE "SP_MAT"
1001 !*************************************************
1002 !*
1003 !* FILE       :  SP_MAT
1004 !* DESCRIPTION:  Program for Measurement Vth
1005 !*                       & Capacitance
1006 !* AUTHOR     :  Tomohiko Matsui
1007 !* CREATED    :  11/02/1995
1008 !* MODIFIED   :
1009 !* PRODUCT    :  HP E5250A
1010 !* REVISION   :  Rev.A.01.00
1011 !*
1012 !*   (c) Copyright 1995 Hewlett-Packard Co,
1013 !*              All rights reserved.
1014 !*
1015 !*
1016 !*  Customer shall have the personal, non-
1017 !* transferable rights to use, copy or modify
1018 !* this SAMPLE PROGRAM for Customer's internal
1019 !* operations.  Customer shall use the SAMPLE
1020 !* PROGRAM solely and exclusively for its own
1021 !* purpose and shall not license, lease, market
1022 !* or distribute the SAMPLE PROGRAM or modification
1023 !* or any part thereof.
1024 !*
1025 !*  HP shall not be liable for the quality,
1026 !* performance or behavior of the SAMPLE PROGRAM.
1027 !* HP especially disclaims that the operation of
1028 !* the SAMPLE PROGRAM shall be uninterrupted or
1029 !* error free.  This SAMPLE PROGRAM is provided
1030 !* AS IS.
1031 !*
1032 !*  HP DISCLAIMS THE IMPLIED WARRANTIES OF
1033 !* MERCHANTABILITY AND FITNESS FOR A PARTICULAR
1034 !* PURPOSE.
1035 !*
1036 !*  HP shall not be liable for any infringement
1037 !* of any patent, trademark, copyright or other
1038 !* proprietary rights by the SAMPLE PROGRAM or
1039 !* its use.  HP does not warrant that the SAMPLE
1040 !* PROGRAM is free from infringements or such
1041 !* rights of third parties.  However, HP will not
1042 !* knowingly infringe or deliver a software that
1043 !* infringes the patent, trademark, copyright or
1044 !* other proprietary right of a third party.
1045 !*
1046 !*************************************************
1047  !
1048  !=========================================================================
1049  !////////////////////// MAIN ROUTINE /////////////////////////////////////
1050  !=========================================================================
1051  !
1052  ! COM /Vfp_com_data/ Setup_data$[14000] ! for VFP Upload Library
1053                                 !
1054  CALL Init_setting              ! Initialize variable & Set Constant
1055                                 !
1056  CALL Init_instrument           ! Instrument initialize
1057                                 !
1058  CALL Meas_vth                  ! Vth measurement
1059                                 !
1060  CALL Meas_c                    ! C measurement
1061                                 !
1062 Complete_test:                  ! End of test
1063  CALL Test_end
1064  DISP "Vth & C Measurement is Completed!!"
1065  !
1066  END
1067!
1068!=========================================================================
1069!////////////////////// SUB ROUTINE //////////////////////////////////////
1070!=========================================================================
1071!
1072!=======================================================================
1073! Initialize variables
1074!-----------------------------------------------------------------------
1075 Init_setting:SUB Init_setting
1076    COM /Io1/ @Hp415x,INTEGER Hpib_sc,Adrs415x
1077    COM /Io2/ @Hp5250,@Hp4284,INTEGER Adrs5250,Adrs4284
1078    COM /Print/ INTEGER Prn_adrs,Prn_enab
1079    COM /Comm/ Usercomm$[30]
1080    COM /Err/ Err_num(1:6),Err_message$(1:6)[60]
1081    COM /Info1/ Test_num
1082    !
1083    DIM Out_str$[100]
1084    !
1085    !--------- HP-IB Setup -------------------------------------------------
1086    INTEGER Ad415x,Ad4284,Ad5250
1087    !
1088    Hpib_sc=7                    ! HP-IB Select code
1089    !
1090    Ad415x=17                    ! HP 4155/4156 HP-IB Address
1091    Ad4284=24                    ! HP 4284 HP-IB Address
1092    Ad5250=22                    ! HP E5250A HP-IB Address
1093    !
1094    Adrs415x=Hpib_sc*100+Ad415x  ! HP 4155/4156 HP-IB Address
1095    Adrs4284=Hpib_sc*100+Ad4284  ! HP 4284 HP-IB Address
1096    Adrs5250=Hpib_sc*100+Ad5250  ! HP E5250A HP-IB Address
1097    !
1098    ON ERROR GOTO Addr_error
1099    ASSIGN @Hp415x TO Adrs415x   ! HP 4155/4156 I/O Path assigned
1100    ASSIGN @Hp4284 TO Adrs4284   ! HP 4284 I/O Path assigned
1101    ASSIGN @Hp5250 TO Adrs5250   ! HP E5250A I/O Path assigned
1102    OFF ERROR 
1103    !
1104    !--------- Printer Address & Enable/Disable Flag setup -----------------
1105    Ad_prn=1                     ! Printer HP-IB Address
1106    Prn_adrs=Hpib_sc*100+Ad_prn  ! Printer HP-IB Address
1107    !
1108    Prn_enab=0                   ! 0 : Printout disable, 1 : Printout enable
1109    !
1110    !--------- User Comment Set --------------------------------------------
1111    Usercomm$="Vth & C Meas. Sample Program"  ! for Report header
1112    !
1113    Test_num=0                                ! Test number for Report
1114    !
1115    !--------- Report Header Output ----------------------------------------
1116    CLEAR SCREEN
1117    OUTPUT Out_str$ USING "2A,2X,3A,2X,11A,2X,11A,2X,11A,2X,K";" #","P/F","  Min."," Meas.","  Max.","Comment"
1118    PRINT "Comment   : ";Usercomm$
1119    PRINT "Test Time : ";DATE$(TIMEDATE);" ";TIME$(TIMEDATE)
1120    PRINT USING "#,K";Out_str$
1121    IF Prn_enab=1 THEN 
1122      OUTPUT Prn_adrs;"Comment   : ";Usercomm$
1123      OUTPUT Prn_adrs;"Test Time : ";DATE$(TIMEDATE);" ";TIME$(TIMEDATE)
1124      OUTPUT Prn_adrs USING "#,K";Out_str$
1125    END IF
1126    !
1127    SUBEXIT
1128 Addr_error:!
1129    BEEP 
1130    DISP "### I/O Path Assign Error ## ";ERRM$
1131    OFF ERROR 
1132    STOP
1133  SUBEND
1134 !
1135 !
1136 !=======================================================================
1137 ! Initialize Instrument
1138 !-----------------------------------------------------------------------
1139 Init_instrument:SUB Init_instrument
1140    CALL Reset415x                         ! HP 4155/4156 Reset
1141    DISP "HP 4155/4156 Reset Completed"
1142                                           !
1143    CALL Reset4284                         ! HP 4284 Reset
1144    DISP "HP 4284A Reset Completed"
1145                                           !
1146  ! CALL Cal415x                           ! HP 4155/4156 Calibration
1147  ! DISP "HP 4155/4156 Calibration Completed"
1148                                           !
1149    CALL Reset5250                         ! HP E5250A Reset
1150    CALL Set5250init                       ! HP E5250A Initial setting
1151    DISP "HP E5250A Initialization Completed"
1152    !
1153  SUBEND
1154 !
1155 !
1156 !=======================================================================
1157 ! Vth measurement routine
1158 !-----------------------------------------------------------------------
1159 Meas_vth:SUB Meas_vth
1160    COM /Io1/ @Hp415x,INTEGER Hpib_sc,Adrs415x
1161    COM /Io2/ @Hp5250,@Hp4284,INTEGER Adrs5250,Adrs4284
1162    COM /Print/ INTEGER Prn_adrs,Prn_enab
1163    COM /File_name1/ Param_file$[12],Save_file$[12]
1164    COM /Info1/ Test_num
1165    ! COM /Vfp_com_data/ Setup_data$[14000] ! for VFP Upload Library
1166    !
1167    DIM Test_comm$[30],Out_str$[100],Channel$[100]
1168    !
1169    !--------- Constant Definition -----------------------------------------
1170    Test_comm$="MOSFET Vth Measurement"
1171    ! Test_comm$=FNGet_vfp_comment$(Setup_data$,Setup_num) ! for VFP Upload Library
1172    !
1173    Param_file$="E5252.MES"               ! Vth measurement setup file
1174    !
1175    Vth_max=2.0                           ! Vth Maximun Limit
1176    Vth_min=.1                            ! Vth Minimun Limit
1177    !
1178    Channel$="(@10101,10202,10303,10404)" ! Channel List to be closed
1179    !
1180    !--------- Instrument Reset & Setup for measurement --------------------
1181    ! HP 4155/4156 Setup Data File Get & Setup
1182    OUTPUT @Hp415x;":MMEM:LOAD:STAT 0,'"&Param_file$&"','DISK'"
1183    OUTPUT @Hp415x;"*OPC?"
1184    ENTER @Hp415x;A
1185    DISP "HP 4155/4156 Setup Completed"
1186    !
1187    !--------- Connect to DUT ----------------------------------------------
1188    OUTPUT @Hp5250;":ROUT:CLOS "&Channel$
1189    OUTPUT @Hp5250;"*OPC?"                 !
1190    ENTER @Hp5250;A
1191    ! Connect_vfp(Setup_data$,Setup_num)   ! for VFP Upload Library
1192    DISP "Connected MOSFET"
1193    !
1194    !--------- Measurement -------------------------------------------------
1195    OUTPUT @Hp415x;":PAGE:GLIS"
1196    OUTPUT @Hp415x;":DISP:WIND:STAT ON"
1197    OUTPUT @Hp415x;":PAGE:SCON:SING"
1198    OUTPUT @Hp415x;"*OPC?"
1199    ENTER @Hp415x;A
1200    !
1201    OUTPUT @Hp415x;":DISP:WIND:STAT OFF"
1202    OUTPUT @Hp415x;":TRAC? 'VTH'"
1203    ENTER @Hp415x;Vth
1204    DISP "Vth Measurement Completed"
1205    !
1206    !--------- Save Measurement Data ---------------------------------------
1207    ! OUTPUT @Hp415x;":MMEM:STOR:TRAC DEF,'VTH.DAT','DISK'"
1208    ! OUTPUT @Hp415x;"*OPC?"
1209    ! ENTER @Hp415x;A
1210    !
1211    !--------- Connection All Open -----------------------------------------
1212    OUTPUT @Hp5250;":ROUT:OPEN:CARD ALL"   ! All card set OPEN
1213    OUTPUT @Hp5250;"*OPC?"                 !
1214    ENTER @Hp5250;A
1215    ! Connect_vfp(Setup_data$,Setup_num)   ! for VFP Upload Library
1216    DISP "Disconnected MOSFET"
1217    !
1218    !--------- Test measurement data ---------------------------------------
1219    IF Vth<Vth_min OR Vth>Vth_max THEN ! Measurement Vth data test
1220      Result$=" F"                         ! Failed
1221    ELSE
1222      Result$=" P"                         ! Passed
1223    END IF
1224    !
1225    !--------- Reset Instrument --------------------------------------------
1226    Test_num=Test_num+1
1227    OUTPUT Out_str$ USING Img1;Test_num,Result$,Vth_min,Vth,Vth_max,Test_comm$
1228    PRINT USING "#,K";Out_str$
1229    IF Prn_enab=1 THEN 
1230      OUTPUT Prn_adrs USING "#,K";Out_str$
1231    END IF
1232 Img1:IMAGE 2D,2X,3A,1X,M2D.3DESZZZ,1X,M2D.3DESZZZ,1X,M2D.3DESZZZ,2X,K
1233    !
1234    CALL Reset5250                         ! HP E5250A Reset
1235    CALL Reset415x                         ! HP 4155/4156 Reset
1236    DISP "Vth Measurement Completed"
1237  SUBEND
1238 !
1239 !
1240 !=======================================================================
1241 ! C measurement & Correction routine
1242 !-----------------------------------------------------------------------
1243 Meas_c:SUB Meas_c
1244    COM /Io1/ @Hp415x,INTEGER Hpib_sc,Adrs415x
1245    COM /Io2/ @Hp5250,@Hp4284,INTEGER Adrs5250,Adrs4284
1246    COM /Print/ INTEGER Prn_adrs,Prn_enab
1247    COM /Info1/ Test_num
1248    ! COM /Vfp_com_data/ Setup_data$[14000] ! for VFP Upload Library
1249    !
1250    DIM Test_comm$[30],Out_str$[100],Channel$[100]
1251    !
1252    !--------- Constant Definition -----------------------------------------
1253    Test_comm$="Capacitance Measurement"   ! for Report
1254    ! Test_comm$=FNGet_vfp_comment$(Setup_data$,Setup_num) ! for VFP Upload Library
1255    !
1256    Capa_max=2.000E-11           ! Capacitance Maximun Limit
1257    Capa_min=8.00E-12            ! Capacitance Minimun Limit
1258    !
1259    Sig_volt=.03                 ! Measurement signal voltage (V)
1260    Meas_freq=1.00E+5            ! Measurement Frequency (Hz)
1261    Cable_len=2                  ! Used Cable Length (M)
1262    !
1263    Clen_hptriax=1.5             ! Used HP Triax Cable Length (M)
1264    Clen_usrtriax_h=0            ! Used User Triax Cable [High] Length (M)
1265    Clen_usrtriax_l=0            ! Used User Triax Cable [Low] Length (M)
1266    Clen_usrcoax_h=1.0           ! Used User Coax Cable [High] Length (M)
1267    Clen_usrcoax_l=1.0           ! Used User Coax Cable [Low] Length (M)
1268    !
1269    Channel$="(@10905,11006)"    ! Channel List to be closed
1270    !
1271    !--------- Instrument Reset & Setup for measurement --------------------
1272    OUTPUT @Hp4284;"FUNC:IMP:RANG:AUTO ON"     ! AUTO range set
1273    OUTPUT @Hp4284;"BIAS:VOLT MIN"             ! Bias voltage set 0V
1274    OUTPUT @Hp4284;"APER MED"                  ! Integ. time set Medle
1275    OUTPUT @Hp4284;"COMP OFF"                  ! Comparator Mode OFF
1276    OUTPUT @Hp4284;"FORM ASC"                  ! Data Format ascii
1277    OUTPUT @Hp4284;"FUNC:IMP CPG"              ! Measurement Mode set Cp-G
1278    OUTPUT @Hp4284;"VOLT "&VAL$(Sig_volt)      ! Signal voltage set
1279    OUTPUT @Hp4284;"FREQ "&VAL$(Meas_freq)     ! Measurement Feaquency set
1280    OUTPUT @Hp4284;"CORR:LENG "&VAL$(Cable_len)&"M" ! Cable correction set
1281    OUTPUT @Hp4284;"*OPC?"
1282    ENTER @Hp4284;A
1283    DISP "HP 4284A Setup Completed"
1284    !
1285    !--------- Connect to DUT ----------------------------------------------
1286    OUTPUT @Hp5250;":ROUT:CLOS "&Channel$
1287    OUTPUT @Hp5250;"*OPC?"
1288    ENTER @Hp5250;A
1289    ! Connect_vfp(Setup_data$,Setup_num)       ! for VFP Upload Library
1290    DISP "Connected Capacitance"
1291    !
1292    !--------- Measurement -------------------------------------------------
1293    OUTPUT @Hp4284;"TRIG:SOUR BUS"
1294    OUTPUT @Hp4284;"ABOR"
1295    OUTPUT @Hp4284;"INIT"
1296    OUTPUT @Hp4284;"*TRG"
1297    ENTER @Hp4284;Raw_cap,Raw_g,Stat
1298    DISP "C Measurement Completed"
1299    !
1300    !--------- Connection All Open -----------------------------------------
1301    OUTPUT @Hp5250;":ROUT:OPEN:CARD ALL"   ! All card set OPEN
1302    OUTPUT @Hp5250;"*OPC?"                 !
1303    ENTER @Hp5250;A
1304    ! Connect_vfp(Setup_data$,Setup_num)   ! for VFP Upload Library
1305    !
1306    !--------- C Correction routine ----------------------------------------
1307    Ccompen_5250(Meas_freq,Clen_hptriax,Clen_usrtriax_h,Clen_usrtriax_l,Clen_usrcoax_h,Clen_usrcoax_l,Raw_cap,Raw_g,Corr_cap,Corr_g)
1308    DISP "C Compensation Completed"
1309    !
1310    IF Corr_cap=MAXREAL THEN                ! C Compensation Error check
1311      BEEP 
1312      DISP "C Compensation Error !!"
1313      Corr_cap=0
1314    END IF
1315    !
1316    !--------- Test measurement data ---------------------------------------
1317    IF Corr_cap<Capa_min OR Corr_cap>Capa_max THEN    ! Compensated C data test
1318      Result$=" F"                         ! Failed
1319    ELSE
1320      Result$=" P"                         ! Passed
1321    END IF
1322    !
1323    !--------- Report output -----------------------------------------------
1324    Test_num=Test_num+1
1325    OUTPUT Out_str$ USING Img1;Test_num,Result$,Capa_min,Corr_cap,Capa_max,Test_comm$
1326    PRINT USING "#,K";Out_str$
1327    IF Prn_enab=1 THEN 
1328      OUTPUT Prn_adrs USING "#,K";Out_str$
1329    END IF
1330 Img1:IMAGE 2D,2X,3A,2X,1D.3DESZZ,4X,1D.3DESZZ,4X,1D.3DESZZ,4X,K
1331    !
1332    !--------- Instrument Reset --------------------------------------------
1333    CALL Reset5250                         ! HP E5250A Reset
1334    CALL Reset4284                         ! HP 4284 Reset
1335    DISP "C Measurement Completed"
1336  SUBEND
1337 !
1338 !
1339 !=======================================================================
1340 ! HP 4155/4156 Reset
1341 !-----------------------------------------------------------------------
1342 Reset415x:SUB Reset415x
1343    COM /Io1/ @Hp415x,INTEGER Hpib_sc,Adrs415x
1344    !-----------------------------------------------------------------------
1345    T_out=3                                ! Timeout set (sec)
1346    !
1347    ON ERROR GOTO Reset_error
1348    ON TIMEOUT Hpib_sc,T_out GOTO Time_out
1349    !
1350    CLEAR @Hp415x
1351    OUTPUT @Hp415x;"*RST"                  ! Device reset
1352    OUTPUT @Hp415x;"*CLS"                  ! Clear status data
1353    OUTPUT @Hp415x;":STAT:PRES"            ! Preset event enable mask register
1354    OUTPUT @Hp415x;":DISP:WIND:STAT OFF"   ! Screen update off
1355    OUTPUT @Hp415x;":CAL:AUTO OFF"         ! Auto calibration off
1356    OUTPUT @Hp415x;"*ESE 60;*SRE 32;*OPC?" ! Event status/service request enable register setup
1357    ENTER @Hp415x;A
1358    SUBEXIT
1359    !--------- SUB END -----------------------------------------------------
1360 Time_out:                                 !
1361    BEEP 
1362    DISP "### HP4155/4156 Initialize Timeout ###"
1363    OFF TIMEOUT 
1364    OFF ERROR 
1365    STOP
1366 Reset_error:                              !
1367    BEEP 
1368    DISP "### HP4155/4156 Initialize Fail ## ";ERRM$
1369    OFF TIMEOUT 
1370    OFF ERROR 
1371    STOP
1372    !
1373  SUBEND
1374 !
1375 !
1376 !=======================================================================
1377 ! HP E5250A Reset
1378 !-----------------------------------------------------------------------
1379 Reset5250:SUB Reset5250
1380    COM /Io1/ @Hp415x,INTEGER Hpib_sc,Adrs415x
1381    COM /Io2/ @Hp5250,@Hp4284,INTEGER Adrs5250,Adrs4284
1382    !-----------------------------------------------------------------------
1383    T_out=3                                ! Timeout set (sec)
1384    !
1385    ON ERROR GOTO Reset_error
1386    ON TIMEOUT Hpib_sc,T_out GOTO Time_out
1387    !
1388    CLEAR @Hp5250
1389    OUTPUT @Hp5250;"*RST"                  ! Device reset
1390    OUTPUT @Hp5250;"*CLS"                  ! Clear status data
1391    OUTPUT @Hp5250;"*ESE 60;*SRE 32;*OPC?" ! Event status/service request enable register setup
1392    ENTER @Hp5250;A
1393    SUBEXIT
1394    !--------- SUB END -----------------------------------------------------
1395 Time_out:                                 !
1396    BEEP 
1397    DISP "### HP E5250A Initialize Timeout ###"
1398    OFF TIMEOUT 
1399    OFF ERROR 
1400    STOP
1401 Reset_error:                              !
1402    BEEP 
1403    DISP "### HP E5250A Initialize Fail ## ";ERRM$
1404    OFF TIMEOUT 
1405    OFF ERROR 
1406    STOP
1407    !
1408  SUBEND
1409 !
1410 !
1411 !=======================================================================
1412 ! HP 4284 Reset
1413 !-----------------------------------------------------------------------
1414 Reset4284:SUB Reset4284
1415    COM /Io1/ @Hp415x,INTEGER Hpib_sc,Adrs415x
1416    COM /Io2/ @Hp5250,@Hp4284,INTEGER Adrs5250,Adrs4284
1417    !-----------------------------------------------------------------------
1418    T_out=3                                ! Timeout set (sec)
1419    !
1420    ON ERROR GOTO Reset_error
1421    ON TIMEOUT Hpib_sc,T_out GOTO Time_out
1422    !
1423    CLEAR @Hp4284
1424    OUTPUT @Hp4284;"*RST"                  ! Device reset
1425    OUTPUT @Hp4284;"*CLS"                  ! Clear status data
1426    OUTPUT @Hp4284;"*ESE 60;*SRE 32;*OPC?" ! Event status/service request enable register setup
1427    ENTER @Hp4284;A
1428    SUBEXIT
1429    !--------- SUB END -----------------------------------------------------
1430 Time_out:                                 !
1431    BEEP 
1432    DISP "### HP4284 Initialize Timeout ###"
1433    OFF TIMEOUT 
1434    OFF ERROR 
1435    STOP
1436 Reset_error:                              !
1437    BEEP 
1438    DISP "### HP4284 Initialize Fail ## ";ERRM$
1439    OFF TIMEOUT 
1440    OFF ERROR 
1441    STOP
1442    !
1443  SUBEND
1444 !
1445 !
1446 !=======================================================================
1447 ! HP4155/4156 Calibration
1448 !-----------------------------------------------------------------------
1449 Cal415x:SUB Cal415x
1450    COM /Io1/ @Hp415x,INTEGER Hpib_sc,Adrs415x
1451    !-----------------------------------------------------------------------
1452    OUTPUT @Hp415x;":PAGE:SYST:CDI"
1453    OUTPUT @Hp415x;":DISP:WIND:STAT ON"
1454    OUTPUT @Hp415x;":CAL:ALL?"
1455    ENTER @Hp415x;A
1456    SELECT A
1457    CASE 0
1458      OUTPUT @Hp415x;":PAGE:GLIS"
1459      OUTPUT @Hp415x;":DISP:WIND:STAT OFF"
1460    CASE ELSE
1461      PRINT 
1462      PRINT "     ##### Calibration FAIL ,TEST ABORTED #####"
1463      STOP
1464    END SELECT
1465  SUBEND
1466 !
1467 !
1468 !==========================================================================
1469 ! HPE5250 Connection Rule/Sequence setup
1470 !--------------------------------------------------------------------------
1471 Set5250init:SUB Set5250init
1472    COM /Io2/ @Hp5250,@Hp4284,INTEGER Adrs5250,Adrs4284
1473    ! COM /Vfp_com_data/ Setup_data$[14000] ! for VFP Upload Library
1474    ! Adrs=Adrs5250
1475    ! CALL Load_vfp_data(Adrs,"VFP_FILE",Setup_data$)
1476    ! CALL Init_vfp_setup(Setup_data$)
1477    !
1478    OUTPUT @Hp5250;":ROUT:FUNC NCON"          ! Set Normal Configuration
1479    OUTPUT @Hp5250;":ROUT:BIAS:STAT ALL,OFF"  ! All card set bias state OFF
1480    OUTPUT @Hp5250;":ROUT:CONN:RULE ALL,SROU" ! All card set Single Route Rule
1481    OUTPUT @Hp5250;":ROUT:CONN:SEQ ALL,BBM"   ! All card set Break befor Make
1482    OUTPUT @Hp5250;":ROUT:OPEN:CARD ALL"      ! All card set OPEN
1483    OUTPUT @Hp5250;"*OPC?"                    !
1484    ENTER @Hp5250;A
1485  SUBEND
1486 !
1487 !
1488 !=======================================================================
1489 Test_end: SUB Test_end
1490 !=======================================================================
1491    COM /Io1/ @Hp415x,INTEGER Hpib_sc,Adrs415x
1492    COM /Io2/ @Hp5250,@Hp4284,INTEGER Adrs5250,Adrs4284
1493    !-----------------------------------------------------------------------
1494    OUTPUT @Hp5250;"*RST"                  ! HPE5250 Device reset
1495    OUTPUT @Hp5250;"*CLS"                  ! HPE5250 Clear status data
1496    OUTPUT @Hp4284;"*RST"                  ! HP 4284 Device reset
1497    OUTPUT @Hp4284;"*CLS"                  ! HP 4284 Clear status data
1498    OUTPUT @Hp415x;"*RST"                  ! HP 415X Device reset
1499    OUTPUT @Hp415x;"*CLS"                  ! HP 415X Clear status data
1500    OUTPUT @Hp415x;":DISP:WIND:STAT ON"    ! HP 415X Screen update on
1501    OUTPUT @Hp415x;":DISP:WIND:ALL INST"   ! HP 415X All instrument screen
1502    LOCAL Hpib_sc
1503    !
1504    ASSIGN @Hp415x TO *                    !
1505    ASSIGN @Hp5250 TO *                    !
1506    ASSIGN @Hp4284 TO *                    !
1507    !
1508  SUBEND
1509 !
